* mz06_Casmin_gml.do (März 2009)
* Quelle: http://www.gesis.org/fileadmin/upload/dienstleistung/tools_standards/
* mikrodaten_tools/CASMIN/Stata/mz06_Casmin_gml.do
version 10.1 // Stata for Windows version 10.1
clear
capture log close
set more off
set memory 500m
set dp comma
* Im folgenden Kommando "
" durch das lokale Arbeitsverzeichnis ersetzen
cd
log using casmin06.log, replace
/* ***************************************************************************
GESIS - Leibniz-Institut für Sozialwissenschaften
German Microdata Lab (GML)
Postfach 12 21 55
68072 Mannheim
Tel.: 0621/1246-265 Fax: 0621/1246-100
E-Mail: gml@gesis.org
Tony Siegel, Delia Jäger, Bernhard Schimpl-Neimanns
Version: 30.03.2009
STATA-Job zur Umsetzung der CASMIN-Bildungsklassifikation mit dem
Mikrozensus 2006
Bei Nutzung dieser Routine bitte wie folgt zitieren:
(hier wird auch die Skalenkonstruktion beschrieben)
Lechert, Y.; Schroedter, J.; Lüttinger, P. (2006): Die Umsetzung der
Bildungsskala CASMIN für die Volkszählung 1970, die Mikrozensus-Zusatzerhebung
1971 und die Mikrozensen 1976-2004. ZUMA-Methodenbericht 2006/12.
http://www.gesis.org/dienstleistungen/tools-standards/mikrodaten-tools/casmin/
Literaturhinweise, Quellen:
Brauns, H./Scherer, S./Steinmann, S., 2003: The CASMIN Educational
Classification in International Comparative Research. S. 196-221 in:
Hoffmeyer-Zlotnik, J.H.P; Wolf, C. (Hrsg): Advances in Cross-National
Comparison. An European Working Book for Demographic and
Socio-Economic Variables. Amsterdam.
Datenbasis: Mikrozensus 2006, Scientific Use File
Datenbeschreibung: http://www.gesis.org/dienstleistungen/daten/
amtliche-mikrodaten/mikrozensus/grundfile/mz2006/
Programm: http://www.gesis.org/fileadmin/upload/dienstleistung/tools_standards/
mikrodaten_tools/CASMIN/Stata/mz06_Casmin_gml.do
**************************************************************************** */
* Im folgenden Kommando ist "" durch den lokalen Dateinamen
* zu ersetzen; ggf. ohne Variablenauswahl.
use EF287 EF309 EF310 EF311 EF312 using ""
******************************************************************************
* Harmonisierte CASMIN-Klassifikation (MZ2006) (cas / casa)
* Allgemein bildender Abschluss (schul)
recode EF310 (0 9=0 "[0] entf.o.A.") ///
(1=2 "[2] HS/VS") ///
(2 3=3 "[3] RS/POS") ///
(4 5=4 "[4] FHR/ABI") , generate(schul)
replace schul=1 if (EF309==8)
label variable schul "Allgemein bildender Abschluss"
label define schul 1 "[1] kein AB", add modify
******************************************************************************
* Berufsbildender Abschluss (ber)
recode EF312 (0 99=0 "[0] entf./o.A.") ///
(1 2 3 4 5 6=2 "[2] Ausb.") ///
(7 8=3 "[3] FH") ///
(9 10=4 "[4] Uni"), generate(ber)
replace ber=1 if (EF311==8)
label variable ber "Berufsbildender Abschluss"
label define ber 1 "[1] kein BA", add modify
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul ber, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT).
generate cas=99
replace cas=99 if (schul==0 | ber==0)
replace cas=0 if (((schul==0 | schul==1) & ///
ber==1) | (schul==1 & ber==0))
replace cas=1 if (schul==2 & (ber==0 | ber==1))
replace cas=2 if ((schul==0 | schul==1 | schul==2) & ber==2)
replace cas=3 if (schul==3 & (ber==0 | ber==1))
replace cas=4 if (schul==3 & ber==2)
replace cas=5 if (schul==4 & (ber==0 | ber==1))
replace cas=6 if (schul==4 & ber==2)
replace cas=7 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==3)
replace cas=8 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==4)
lab variable cas "CASMIN-Klassifikation des GML"
label define cas 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas cas
tab cas, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa=cas
replace casa=9 if (EF287==1)
label variable casa "CASMIN-Klassifikation des GML in Ausb. separat)"
label define casa 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa casa
tab casa, miss
* ENDE harmonisierte CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* Zeitpunktbezogene CASMIN-Klassifikation (MZ2006) (cas06 / casa06)
* Allgemein bildender Abschluss (schul06)
recode EF310 (0=0 "[0] entf.") ///
(9=2 "[2] o.A. zur Art") ///
(1=3 "[3] HS/VS") ///
(2 3=4 "[4] RS/POS") ///
(4 5=5 "[5] FHR/ABI"), generate(schul06)
replace schul06=1 if (EF309==8)
label variable schul06 "Allgemein bildender Abschluss"
label define schul06 1 "[1] kein AB", add modify
******************************************************************************
* Berufsbildender Abschluss (ber06)
recode EF312 (0=0 "[0] entf.") ///
(1 2=3 "[3] Anlernausb. (BVJ)") ///
(3 4 5 6=4 "[4] Ausb./Meist./Techn.") ///
(7=5 "[5] Verw.-FH") ///
(8=6 "[6] FH") ///
(9 10=7 "[7] Uni") ///
(99=1 "[1] o.A."), generate(ber06)
replace ber06=2 if (EF311==8)
label variable ber06 "Berufsbildender Abschluss"
label define ber06 2 "[2] kein AB", add modify
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul06 ber06, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTBEZOGEN)
generate cas06=99
replace cas06=99 if ((schul06==0 | ber06==0))
replace cas06=0 if (((schul06==0 | schul06==1) & ///
(ber06==1 | ber06==2 | ber06==3)) | ///
(schul06==1 & ber06==0))
replace cas06=1 if ((schul06==2 | schul06==3) & ///
(ber06==0 | ber06==1 | ber06==2 | ber06==3))
replace cas06=2 if ((schul06==0 | schul06==1 | ///
schul06==2 | schul06==3) & ///
(ber06==4 | ber06==5))
replace cas06=3 if (schul06==4 & (ber06==0 | ///
ber06==1 | ber06==2 | ber06==3))
replace cas06=4 if (schul06==4 & (ber06==4 | ber06==5))
replace cas06=5 if (schul06==5 & (ber06==0 | ///
ber06==1 | ber06==2 | ber06==3))
replace cas06=6 if (schul06==5 & (ber06==4 | ber06==5))
replace cas06=7 if ber06==6
replace cas06=8 if ber06==7
lab variable cas06 "CASMIN-Klassifikation des GML"
label define cas06 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas06 cas06
tab cas06, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTSBEZOGEN) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa06=cas06
replace casa06=9 if (EF287==1)
label variable casa06 "CASMIN-Klassifikation des GML in Ausb. separat"
label define casa06 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa06 casa06
tab casa06, miss
* ENDE zeitpunktbezogene CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* OPTIONAL: Auschluss der Personen, die unter 15 Jahre alt sind.
* keep if (EF44>=15) oder z.B.
* tab casa06 if (EF44>=15)
******************************************************************************
exit