* mz07_Casmin_gml.do
* Quelle: http://www.gesis.org/dienstleistung/tools_standards/
* mikrodaten_tools/ISEI/Stata/mz07_Casmin_gml.do
version 10.1 // Stata for Windows version 10.1
clear
capture log close
set more off
set memory 500m
set dp comma
* Im folgenden Kommando "
" durch das lokale Arbeitsverzeichnis ersetzen
cd
log using casmin07.log, replace
/* ***************************************************************************
GESIS - Leibniz-Institut für Sozialwissenschaften
German Microdata Lab (GML)
Postfach 12 21 55
68072 Mannheim
Tel.: 0621/1246-265 Fax: 0621/1246-100
E-Mail: gml@gesis.org
Delia Jäger, Tony Siegel, Bernhard Schimpl-Neimanns
Version: 28.01.2010
******************************************************************************/
/* STATA-Syntax zur Umsetzung der CASMIN-Bildungsklassifikation mit dem
Mikrozensus 2007
Bei Nutzung dieser Routine bitte wie folgt zitieren:
(hier wird auch die Skalenkonstruktion beschrieben)
Lechert, Y.; Schroedter, J.; Lüttinger, P. (2006): Die Umsetzung der
Bildungsskala CASMIN für die Volkszählung 1970, die Mikrozensus-Zusatzerhebung
1971 und die Mikrozensen 1976-2004. ZUMA-Methodenbericht 2006/12.
http://www.gesis.org/dienstleistungen/tools-standards/mikrodaten-tools/casmin/
Literaturhinweise, Quellen:
Brauns, H./Scherer, S./Steinmann, S., 2003: The CASMIN Educational
Classification in International Comparative Research. S. 196-221 in:
Hoffmeyer-Zlotnik, J.H.P; Wolf, C. (Hrsg): Advances in Cross-National
Comparison. An European Working Book for Demographic and
Socio-Economic Variables. Amsterdam.
Datenbasis: Mikrozensus 2007, Scientific Use File
Datenbeschreibung: http://www.gesis.org/dienstleistungen/daten/
amtliche-mikrodaten/mikrozensus/grundfile/mz2007/
Programm: http://www.gesis.org/fileadmin/upload/dienstleistung/tools_standards/
mikrodaten_tools/CASMIN/Stata/mz07_Casmin_gml.do
**************************************************************************** */
* Im folgenden Kommando ist "" durch den lokalen Dateinamen
* zu ersetzen; ggf. ohne Variablenauswahl.
use ""
******************************************************************************
* Harmonisierte CASMIN-Klassifikation (MZ2007) (cas / casa)
* Allgemeinbildender Abschluss (schul)
recode EF310 (0 9=0 "[0] entf.o.A.") ///
(1=2 "[2] HS/VS") ///
(2 3=3 "[3] RS/POS") ///
(4 5=4 "[4] FHR/ABI") , generate(schul)
replace schul=1 if (EF309==8)
label variable schul "Allgemeinbildender Abschluss"
label define schul 1 "[1] kein AB", add modify
******************************************************************************
* Berufsbildender Abschluss (ber)
recode EF312 (0 99=0 "[0] entf./o.A.") ///
(1 2 3 4 5 6 11=2 "[2] Ausb.") ///
(7 8=3 "[3] FH") ///
(9 10=4 "[4] Uni"), generate(ber)
replace ber=1 if (EF311==8)
label variable ber "Berufsbildender Abschluss"
label define ber 1 "[1] kein BA", add modify
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul ber, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT)
generate cas=99
replace cas=99 if (schul==0 | ber==0)
replace cas=0 if (((schul==0 | schul==1) & ///
ber==1) | (schul==1 & ber==0))
replace cas=1 if (schul==2 & (ber==0 | ber==1))
replace cas=2 if ((schul==0 | schul==1 | schul==2) & ber==2)
replace cas=3 if (schul==3 & (ber==0 | ber==1))
replace cas=4 if (schul==3 & ber==2)
replace cas=5 if (schul==4 & (ber==0 | ber==1))
replace cas=6 if (schul==4 & ber==2)
replace cas=7 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==3)
replace cas=8 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==4)
lab variable cas "CASMIN-Klassifikation des GML"
label define cas 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas cas
tab cas, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa=cas
replace casa=9 if (EF287==1)
label variable casa "CASMIN-Klassifikation des GML (in Ausb. separat)"
label define casa 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa casa
tab casa, miss
* ENDE harmonisierte CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* Zeitpunktbezogene CASMIN-Klassifikation (MZ2007)
* (cas07 / casa07)
* Allgemeinbildender Abschluss (schul07)
recode EF310 (0=0 "[0] entf.") ///
(9=2 "[2] o.A. zur Art") ///
(1=3 "[3] HS/VS") ///
(2 3=4 "[4] RS/POS") ///
(4 5=5 "[5] FHR/ABI"), generate(schul07)
replace schul07=1 if (EF309==8)
label variable schul07 "Allgemeinbildender Abschluss"
label define schul07 1 "[1] kein AB", add modify
******************************************************************************
* Berufsbildender Abschluss (ber07)
recode EF312 (0=0 "[0] entf.") ///
(1 2=3 "[3] Anlernausb. (BVJ)") ///
(3 4 5 6 11=4 "[4] Ausb./Meist./Techn./Vorber.mittl.Dienst") ///
(7=5 "[5] Verw.-FH") ///
(8=6 "[6] FH") ///
(9 10=7 "[7] Uni") ///
(99=1 "[1] o.A. zur Art"), generate(ber07)
replace ber07=2 if (EF311==8)
label variable ber07 "Berufsbildender Abschluss"
label define ber07 2 "[2] kein AB", add modify
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul07 ber07, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTBEZOGEN)
generate cas07=99
replace cas07=99 if ((schul07==0 | ber07==0))
replace cas07=0 if (((schul07==0 | schul07==1) & ///
(ber07==1 | ber07==2 | ber07==3)) | ///
(schul07==1 & ber07==0))
replace cas07=1 if ((schul07==2 | schul07==3) & ///
(ber07==0 | ber07==1 | ber07==2 | ber07==3))
replace cas07=2 if ((schul07==0 | schul07==1 | ///
schul07==2 | schul07==3) & ///
(ber07==4 | ber07==5))
replace cas07=3 if (schul07==4 & (ber07==0 | ///
ber07==1 | ber07==2 | ber07==3))
replace cas07=4 if (schul07==4 & (ber07==4 | ber07==5))
replace cas07=5 if (schul07==5 & (ber07==0 | ///
ber07==1 | ber07==2 | ber07==3))
replace cas07=6 if (schul07==5 & (ber07==4 | ber07==5))
replace cas07=7 if ber07==6
replace cas07=8 if ber07==7
lab variable cas07 "CASMIN-Klassifikation des GML"
label define cas07 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas07 cas07
tab cas07, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTSBEZOGEN) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa07=cas07
replace casa07=9 if (EF287==1)
label variable casa07 "CASMIN-Klassifikation des GML in Ausb. separat"
label define casa07 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa07 casa07
tab casa07, miss
* ENDE zeitpunktbezogene CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* OPTIONAL: Auschluss der Personen, die unter 15 Jahre alt sind.
* keep if (EF44>=15) oder z.B.
* tab casa07 if (EF44>=15)
******************************************************************************
exit