/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
Diese Datei: mz15_casmin_gml.do
Dateiformat: Dos\Windows
Zeichensatz: Unicode (UTF-8 ohne BOM)
Download: http://www.gesis.org/missy/materials/MZ/tools/casmin
Version: 10/2019
Stata-Syntax zur Umsetzung der CASMIN-Bildungsklassifikation mit dem
Mikrozensus 2015
Version: Stata/MP 15.1 for Windows
Siehe auch:
Lechert, Yvonne; Schroedter, Julia; Lüttinger, Paul (2006): Die Umsetzung der
Bildungsklassifikation CASMIN für die Volkszählung 1970, die Mikrozensus-Zu-
satzerhebung 1971 und die Mikrozensen 1976-2004. ZUMA-Methodenbericht 2006/12.
http://www.gesis.org/fileadmin/upload/forschung/publikationen/gesis_reihen/
gesis_methodenberichte/2006/06_12_lechert.pdf
Datenbasis: Mikrozensus 2015, Scientific Use File
siehe http://www.gesis.org/missy/metadata/MZ/2015/
GESIS - Leibniz-Institut für Sozialwissenschaften
German Microdata Lab (GML)
http://www.gesis.org/das-institut/kompetenzzentren/fdz-german-microdata-lab
E-Mail: gml@gesis.org
- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */
* version 15.1 // Stata/MP 15.1 for Windows
clear
capture log close
set varabbrev off
set dp comma
set more off
* Im folgenden Kommando "
" durch das lokale Arbeitsverzeichnis ersetzen
cd
log using mz15_Casmin_gml.log, text replace
/* Im folgenden Kommando ist "" durch den lokalen Dateinamen zu
ersetzen; ggf. ohne Variablenauswahl - Datenfile ohne User-Missings */
use EF30 /// Bevölkerung: Haupt- oder Nebenwohnsitz
EF44 /// Alter
EF287 /// Schule: gegenwärtiger Besuch (i. d. letzten 4 Wochen)
EF309 /// Allgemeiner Schulabschluss
EF310 /// Höchster allg. Schulabschluss
EF311 /// Beruflicher Abschluss
EF312 /// Höchster berufl. Abschluss
EF952 /// Standardhochrechnungsfaktor Jahr (in 1000)
using "", clear
* Für Querschnittanalysen nicht benötigte Ausfallsätze ausschließen (optional)
* -7 Entfällt (Auswahlbezirk ohne befragten Haushalt) und
* -8 Entfällt (Leerstehende Wohnung, ausgef. Privathaush. u. Gemeinschaftsunt.)
* keep if EF287>-7
******************************************************************************
* Harmonisierte CASMIN-Klassifikation (MZ2015) (cas / casa)
* Beachte: Personen im Alter von 15 Jahren und älter mit derzeitigem Besuch
* einer allgemeinbildenden Schule wird ab MZ 2013 die Frage zum
* allgemeinen Schulabschluss (EF310, Frage 128) nicht mehr gestellt.
* Die Vergleichbarkeit mit Ergebnissen des Mikrozensus bis 2012 ist
* kann deshalb eingeschränkt sein.
* Neu im MZ 2015: -9 "Entfällt (Fehler in der Filterführung)"
* Diese Gruppe wird im Folgenden wie 9 "Keine Angabe" recodiert.
* Allgemeinbildender Abschluss (schul)
recode EF310 (-7 -8=.) /// Entfällt, für Querschnittsausw. nicht relevant
(-3 -5 9=0 "[0] entf./o.A. (incl. Besuch allg.bild. Schule)") ///
(-9=0) /// -9 Entfällt (Fehler in der Filterführung)
(6=1 "[1] kein AB") ///
(1=2 "[2] HS/VS") ///
(2 3 7=3 "[3] RS/POS") ///
(4 5=4 "[4] FHR/ABI"), generate(schul)
replace schul=1 if (EF309==8)
label variable schul "Allgemeinbildender Abschluss"
******************************************************************************
* Berufsbildender Abschluss (ber)
recode EF312 (-7 -8=.) /// Entfällt, für Querschnittsausw. nicht relevant
(-3 -5 99=0 "[0] entf./o.A.") ///
(1/10 16 17=2 "[2] Ausb.") ///
(11/13=3 "[3] FH/Berufsakad.") /// incl. Verw.-FH, Duale HS
(14/15=4 "[4] Uni"), generate(ber)
replace ber=1 if (EF311==8)
label variable ber "Berufsbildender Abschluss"
label define ber 1 "[1] kein BA", add modify
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul ber, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT)
generate cas=99 if schul!=. & ber!=.
replace cas=99 if (schul==0 | ber==0)
replace cas=0 if (((schul==0 | schul==1) & ///
ber==1) | (schul==1 & ber==0))
replace cas=1 if (schul==2 & (ber==0 | ber==1))
replace cas=2 if ((schul==0 | schul==1 | schul==2) & ber==2)
replace cas=3 if (schul==3 & (ber==0 | ber==1))
replace cas=4 if (schul==3 & ber==2)
replace cas=5 if (schul==4 & (ber==0 | ber==1))
replace cas=6 if (schul==4 & ber==2)
replace cas=7 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==3)
replace cas=8 if ((schul==0 | schul==1 | schul==2 | ///
schul==3 | schul==4) & ber==4)
lab variable cas "CASMIN-Klassifikation des GML"
label define cas 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas cas
tab cas, miss
******************************************************************************
* CASMIN-Klassifikation des GML (HARMONISIERT) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa=cas if schul!=. & ber!=.
replace casa=9 if (EF287>=1 & EF287<=2)
label variable casa "CASMIN-Klassifikation des GML (in Ausb. separat)"
label define casa 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa casa
tab casa, miss
* ENDE harmonisierte CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* Zeitpunktbezogene CASMIN-Klassifikation (MZ2015) (cas15 / casa15)
* Allgemeinbildender Abschluss (schul15)
recode EF310 (-7 -8=.) /// Entfällt, für Querschnittsausw. nicht relevant
(-3 -5=0 "[0] entf.") ///
(-9=0) /// -9 Entfällt (Fehler in der Filterführung)
(6=1 "[1] kein AB") /// Abschluss nach hoechstens 7 Jahren Schulbesuch
(9=2 "[2] o.A. zur Art") ///
(1 2=3 "[3] HS/VS, POS 8./9. Kl.") ///
(3 7=4 "[4] RS/POS 10. Kl.") ///
(4 5=5 "[5] FHR/ABI"), generate(schul15)
replace schul15=1 if (EF309==8)
label variable schul15 "Allgemeinbildender Abschluss"
******************************************************************************
* Berufsbildender Abschluss (ber15)
recode EF312 (-7 -8=.) /// Entfällt, für Querschnittsausw. nicht relevant
(-3 -5=0 "[0] entf. (incl. Besuch allg.bild. Schule)") ///
(99=1 "[1] o.A. zur Art") ///
(1 2=3 "[3] Anlernausb. (BVJ)") ///
(3/10 16 17=4 "[4] Ausb./Meist./Techn./Vorber.mittl.Dienst") ///
(12=5 "[5] Verw.-FH") ///
(11 13=6 "[6] FH/Berufsakad.") ///
(14 15=7 "[7] Uni"), generate(ber15)
replace ber15=2 if (EF311==8)
label define ber15 2 "[2] kein AB", add modify
label variable ber15 "Berufsbildender Abschluss"
******************************************************************************
* Kreuztabelle zur Bildung der CASMIN-Klassifikation
tab schul15 ber15, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTBEZOGEN)
generate cas15=99 if schul15!=. & ber15!=.
replace cas15=99 if ((schul15==0 | ber15==0))
replace cas15=0 if (((schul15==0 | schul15==1) & ///
(ber15==1 | ber15==2 | ber15==3)) | ///
(schul15==1 & ber15==0))
replace cas15=1 if ((schul15==2 | schul15==3) & ///
(ber15==0 | ber15==1 | ber15==2 | ber15==3))
replace cas15=2 if ((schul15==0 | schul15==1 | ///
schul15==2 | schul15==3) & ///
(ber15==4 | ber15==5))
replace cas15=3 if (schul15==4 & (ber15==0 | ///
ber15==1 | ber15==2 | ber15==3))
replace cas15=4 if (schul15==4 & (ber15==4 | ber15==5))
replace cas15=5 if (schul15==5 & (ber15==0 | ///
ber15==1 | ber15==2 | ber15==3))
replace cas15=6 if (schul15==5 & (ber15==4 | ber15==5))
replace cas15=7 if ber15==6
replace cas15=8 if ber15==7
lab variable cas15 "CASMIN-Klassifikation des GML - Zeitpunktbezogen"
label define cas15 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (MRO)" ///
4 "[4] 2a (MRM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
99 "[99] entf./o.A."
label values cas15 cas15
tab cas15, miss
******************************************************************************
* CASMIN-Klassifikation des GML (ZEITPUNKTBEZOGEN) mit Beruecksichtigung
* von Personen in gegenw. Ausbildung
generate casa15=cas15 if schul!=. & ber!=.
replace casa15=9 if (EF287>=1 & EF287<=2)
label variable casa15 "CASMIN-Klassifikation des GML in Ausb. separat - Zeitpunktbezogen"
label define casa15 0 "[0] 1a (kein Ab.)" ///
1 "[1] 1b (HSO)" ///
2 "[2] 1c (HSM)" ///
3 "[3] 2b (RSO)" ///
4 "[4] 2a (RSM)" ///
5 "[5] 2c_gen (ABIO)" ///
6 "[6] 2c_voc (ABIM)" ///
7 "[7] 3a (FH)" ///
8 "[8] 3b (UNI)" ///
9 "[9] in Ausbildung" ///
99 "[99] entf./o.A."
label values casa15 casa15
tab casa15, miss
* ENDE zeitpunktbezogene CASMIN-Klassifikation
******************************************************************************
******************************************************************************
* OPTIONAL: Auschluss der Personen, die unter 15 Jahre alt sind.
* keep if (EF44>=15) oder z.B.
* tab casa15 if (EF44>=15)
******************************************************************************
exit